#4 オートカレンダーを作る

完成型

① 下準備としてfunction(機能)欄を作る

①-①祝日表を作ります

①-② スタート月の5ヶ月先の「月」を自動で表示させる

表示ロジックを考える

=IF(n+1 < 12, 真の場合(n+1), 偽の場合(1))

↓セルW5に入れる式
=IF(
  W4+1<12,  // セルW4に1足した数字が12より小さければ
  W4+1,     // セルW4に1を足す
  1         // そうでなければ1にする
)

↓セルW6に入れる式
=IF(
  W4+2<12,  // 2を足したら
  W4+2,
  1
)

=IF(
  W4+1<12,     // "n"であるセルW4に1足した数字が12より小さければ
  W4+1,        // W4に1を足した数字を入れる
  IF(          // そうでなければ、もし、
    W4+1=12,   // その数が12だったら
    12,        // 12にする
    (W4+1)-12  // そうでなければ、n+1した数字から12を引く
  )
)

↓セルW5に入れる式
=IF(
   $W$4+1<12,
   $W$4+1,
   IF(
      $W$4+1=12,
      12,
      $W$4+1-12
   )
)

↓セルW6に入れる式
=IF(
   $W$4+2<12,
   $W$4+2,
   IF(
      $W$4+2=12,
      12,
      $W$4+2-12
   )
)

MOD(割られる数, 割る数) = 割り算の余りを求める

=IF(
   $W$4 + 1 <= 12,        // n+1が12より小さいか、同じなら
   $W$4 + 1,            // n+1を表示
   MOD( ($W$4 + 1), 12)   // そうでない場合(n+1が13以上)、n+1を12で割った余りを表示
)

↓その次の月の式
=IF(
   $W$4 + 2 <= 12,
   $W$4 + 2,
   MOD( ($W$4 + 2), 12)
)

①-③ スタート月から12月を超えた場合に年を1つ繰り上げる。

=IF(
  W4 < W5,     前の月より当月が大きいなら
  X4,         そのまま
  X4 + 1        1足す
)

X5に入る式
=IF(
   AND(W4 < W5, X4 <= $X$4),
   $X$4,
   $X$4 + 1
)

X6に入る式
=IF(
   AND(W5 < W6, X5 <= $X$4),
   $X$4,
   $X$4 + 1
)

X7に入る式
=IF(
   AND(W6 < W7, X6 <= $X$4),
   $X$4,
   $X$4 + 1
)

② カレンダー部分を作る

②-① functionで作った"月"を代入

②-② 28日以降の日付

=DAY(DATE(2016, 10, 31))  //こうすると「31」という数字が取得できます。

=DAY(DATE(2016, 2, 29))
↓
29

=DAY(DATE(2017, 2, 29))
↓
1

=IF(
  DAY(DATE(X8, W8, 29))=29,    //もし[X8]年[W8]月29日がほんとにあれば、29を出して
  29,
  ""
)

=DATE($X$4,$B$4,1)

②-③ 曜日を自動で表示させる

=DATE(年, 月, 日)  //年と月と日のセルを入力します

=DATE($X$4,$W$4,C4)

=TEXT(DATE($X$4,$W$4,C4), "dddd")

=IF(
  C32="",              // もし、29日以降の日付が何もなければ
  "",
  DATE($X$4,$W$4,C32)  // 日付があればの式
)

②-④ 祝日を自動で表示させる

COUNTIF(範囲, "検索条件") となります
COUNTIF(Z5:Z39, DATE(年, 月, 日))  //範囲内に検索条件と同様のものがあれば、その数を返す

=IF(
  COUNTIF(Z5:Z39, DATE(X4, W4, C4)),
  真,
  偽
)

=IF(
  COUNTIF(Z5:Z39, DATE(X4, W4, C4)),
  真,    // 合致した日付の「◯◯の日」という祝日名を入れたい
  ""
)

VLOOKUP(検索値, 範囲, 列番号, [検索方法])　ですので
今回の場合は、

VLOOKUP(2018年10月8日が, 祝日の範囲での場所, 祝日の範囲の何列目を表示させるか, [完全に一致した場合のみ])
↓
VLOOKUP(DATE(X4,W4,C14), Z5:AB39, 3, 0)  //という式を作ります

=IF(
  COUNTIF(Z5:Z39, DATE(X4, W4, C4)),
  VLOOKUP(DATE(X4, W4, C4), Z5:AB39, 3, 0),
  ""
)

③ 土日に色を付ける

まず、色分けしたい範囲を選択します

条件付き書式から、一番下のルールの管理を選びます

+ボタンをクリックします

スタイルからクラシックを選択

数式を使用して、書式設定するセルを決定を選択

=WEEKDAY($D4)=1     // 引数が1もしくは書かなければ、1が日曜日になります（1:日、2:月、3:火、4:水、5:木、6:金、7:土）
=WEEKDAY($D4, 2)=1  // 引数に2を書くと、1は月曜日になります（1:月、2:火、3:水、4:木、5:金、6:土、7:日）
=WEEKDAY($D4, 3)=1  // 引数に3を書くと、1は火曜日になります（1:火、2:水、3:木、4:金、5:土、6:日、7:月）

文字色や背景色を設定します

祝日に文字が入っていれば、色をつける設定

例題が出来たら答え合わせをしてみましょう。